# 《筆記》Flowise & n8n 安裝說明及切換執行批次檔 Batch（52~55）

**URL:** <https://vip.studycamp.tw/t/%E3%80%8A%E7%AD%86%E8%A8%98%E3%80%8Bflowise-n8n-%E5%AE%89%E8%A3%9D%E8%AA%AA%E6%98%8E%E5%8F%8A%E5%88%87%E6%8F%9B%E5%9F%B7%E8%A1%8C%E6%89%B9%E6%AC%A1%E6%AA%94-batch%EF%BC%885255%EF%BC%89/8563>\
**Category:** 自然語言處理\
**Created:** [2025年十二月24日 15:36 UTC](https://vip.studycamp.tw/t/%E3%80%8A%E7%AD%86%E8%A8%98%E3%80%8Bflowise-n8n-%E5%AE%89%E8%A3%9D%E8%AA%AA%E6%98%8E%E5%8F%8A%E5%88%87%E6%8F%9B%E5%9F%B7%E8%A1%8C%E6%89%B9%E6%AC%A1%E6%AA%94-batch%EF%BC%885255%EF%BC%89/8563 "2025-12-24T15:36:10Z")\
**Posts on this page:** 1\
**Page:** 1

<div class="post-metadata">

**Author:** ![sky](https://vip.studycamp.tw/user_avatar/vip.studycamp.tw/sky/32/8098_2.png) [@sky](https://vip.studycamp.tw/u/sky)\
**Post date:** [2025年十二月24日 15:36 UTC](https://vip.studycamp.tw/t/%E3%80%8A%E7%AD%86%E8%A8%98%E3%80%8Bflowise-n8n-%E5%AE%89%E8%A3%9D%E8%AA%AA%E6%98%8E%E5%8F%8A%E5%88%87%E6%8F%9B%E5%9F%B7%E8%A1%8C%E6%89%B9%E6%AC%A1%E6%AA%94-batch%EF%BC%885255%EF%BC%89/8563/1 "2025-12-24T15:36:10Z")

</div>

這堂課的安裝說明有點問題，前面 Flowise 已經痛苦過一次，結果 n8n 又要再來一次。

原因很簡單，Flowise 可以順利執行的版本，對 n8n 卻太舊不支援，結果又重裝（而且是兩個都重裝）幾次。

雖然講師有介紹 nvm（ Node Version Manager，不是 Node Never Mind），但很明顯是事後補充說明。依我之見，應該要一開始就全部安裝，然後才進行個別介紹。

如果你要同時安裝這兩套（Flowise & n8n），這篇筆記應該是最好的安裝說明。

* * *

## ▌安裝步驟

重要！路徑中如果有空白（例如 `C:\Users\Sky Lin\...` ），會導致 nvm & Node.js 執行有問題，所以要安裝到路徑沒有空白的地方。

### 一、安裝 nvm

[**下載 nvm-setup.exe**](https://github.com/coreybutler/nvm-windows/releases)

 ![下載 nvm 安裝程式](https://vip.studycamp.tw/uploads/default/original/2X/c/cfc9f5dff0e52a16fa6276c3277c0c0188640921.png)

安裝過程中，會詢問路徑兩次，第一次是問 nvm 要安裝到哪裡，第二次是問未來執行不同版本的 Node.js 時，要對應的捷徑放置處。

如同前面說的，如果路徑有空白，未來執行時會有問題，處理起來很麻煩，最好的方法就是一開始安裝時，就指定沒有空白的路徑。

以我的安裝為例，第一次第二次的路徑分別為：

```bat
C:\Dev\nvm

```

```bat
C:\Dev\nvm\nodejs

```

 ![安裝 nvm](https://vip.studycamp.tw/uploads/default/original/2X/2/2d0c2c4e4043eadc068fa281efa40e62c9df966e.png)  
 ![未來執行 node.js 的捷徑](https://vip.studycamp.tw/uploads/default/original/2X/e/ecf02b977358db16d46998b981b0fc646656c90c.png)

### 二、安裝 Node.js

我安裝了兩個版本：`20.11.0` 是為了 Flowise、`24.12.0` 是為了 n8n。

你不一定要用一樣的版本， **據說** Flowise 只要是 `20.XX.XX` 就可以，n8n 則是限制在 20.19 和 24.x 之間。但我的版本確定正常運作。

```bat
nvm install 20.11.0

```

```bat
nvm install 24.12.0

```

### 三、安裝 Flowise

```batch
nvm use 20.11.0
npm install -g flowise

```

### 四、安裝 n8n

```batch
nvm use 24.12.0
npm install -g n8n

```

* * *

## ▌執行批次檔 Batch

> 將執行 Flowise & n8n 整合在一個可切換的批次檔（Batch）中。

將最下方的程式，存成 `goflow.bat`（檔名可自取，記得存在有 path 的路徑下）。

要執行 Flowise，就下指令：

```batch
goflow 20

```

要執行 n8n，就下指令：

```batch
goflow 24

```

```bash
@echo off
:: 切換編碼為 UTF-8 以解決中文亂碼問題
chcp 65001 >nul

:: 檢查使用者是否輸入了參數
IF "%1"=="" GOTO MISSING_ARG
IF "%1"=="20" GOTO NODE20
IF "%1"=="24" GOTO NODE24

echo [錯誤] 參數錯誤。請輸入: goflow 20 或 goflow 24
GOTO END

:NODE20
echo ===================================================
echo [模式] 切換至 Node.js v20.11.0 (Flowise 穩定版)
echo ===================================================
call nvm use 20.11.0
IF %ERRORLEVEL% NEQ 0 (
    echo [失敗] 無法切換 Node 版本。請確認是否以「系統管理員身分」執行。
    pause
    EXIT /B
)

:: 設定 Flowise 路徑 (避開空白鍵問題)
set DATABASE_PATH=C:\Flowise\database.sqlite
set API_PATH=C:\Flowise
set LOG_PATH=C:\Flowise\logs

echo 正在啟動 Flowise...
npx flowise start
GOTO END

:NODE24
echo ===================================================
echo [模式] 切換至 Node.js v24.12.0 (n8n 環境)
echo ===================================================
call nvm use 24.12.0
IF %ERRORLEVEL% NEQ 0 (
    echo [失敗] 無法切換 Node 版本。請確認是否以「系統管理員身分」執行。
    pause
    EXIT /B
)

echo 正在啟動 n8n...
:: 這裡不需要設定路徑，因為 n8n 自動會處理好
npx n8n
GOTO END

:MISSING_ARG
echo ===================================================
echo [提示] 請輸入參數來選擇版本。
echo 用法: goflow 20 (啟動 Flowise)
echo 用法: goflow 24 (啟動 n8n)
echo ===================================================
GOTO END

:END
pause

```

* * *

## ▌忠告

問 Gemini（其他的 GAI 也是）常常頭痛醫頭，腳痛醫腳，要 try and error 好幾次，而且愈改愈亂。這篇文章就是痛苦的經驗分享。

**希望大家不用像我，把生命浪費在 install / uninstall 的時間上。**
